var adres:URLRequest = new URLRequest("sarki.mp3");
var ses:Sound = new Sound(adres);
ses.play()

Bunu daha kısa yapmak istersek şunu yazabiliriz;

var ses:Sound = new Sound(new URLRequest("sarki.mp3"));
ses.play()

Bu kodu test edince şarkı çalacaktır. Kodda önce dışardan çağıracağımız şarki.mp3 için bir URLRequest belirttik sonra yeni bir sound oluşturduk ve sonra da sesimizi play komutu ile ile çaldık. Eğer dışardan değilde kütüphaneden bir sesi çalmak istiyorsak kütüphaneye eklediğimiz sesi muzik diye linkage edip kodları şu şekilde değiştirmeliyiz;

var ses:muzik = new muzik();
ses.play();

Burada da ses değişkeninin yeni bir muzik olduğunu belirttik ve sonra oynattık. Eğer sesi belirli bir saniyesinden sonra oynatmak istiyorsak ve belirli bir sayı defa oynatmak istiyorsak son kısmı şöyle değiştirmeliyiz;

ses.play(10000,3)

Parantez içindeki ilk kısım başlama zamanını, virgülden sonraki kısım ise loop’u yani tekrarı belirtir. Bu kodla ses 10. saniyeden sonra başlar ve üç kere çalar. Şimdi sesin çalma anındaki konumunu öğrenmeye çalışalım. Bunun için önce sahneye denetle_btn isminde bir buton koyalım ve sonra şöyle bir kod yazalım;

var ses:Sound = new Sound(new URLRequest("sarki.mp3"));
var kanal:SoundChannel=ses.play()
 
denetle_btn.addEventListener(MouseEvent.CLICK,denetle)
function denetle(e:MouseEvent){
trace("ses şimdi "+Math.round(kanal.position/1000)+"."+" saniyede" )
}

Bu kodla şarkı çalarken denetle_btn butonuna bastıkça şarkının kaçıncı saniyede olduğunu görebiliyoruz. Burada daha önceden de yaptığımız gibi yeni bir ses değişkeni oluşturduk daha sonra bir SoundChannel değişkeni olarak kanal’ı ekledik ve bunla sesi oynattık sonra denetle_btn butonuna tıkladığımızda position ile SoundChannel’in konumunu/pozisyonunu aldık. Şimdi madem şarkı çalınca konumunu öğrenebiliyoruz o zaman şarkıyı stop ettirirken alacağımız konum noktasını daha sonra play ederken başlangıç noktası yaparsak ses için bir play-pause aktivitesi yapabiliriz, aksi taktirde pause işlemini direkt olarak yapacağımız bir komut yok, o halde dediğimizi yapalım; Sahneye basla_btn ve durakla_btn isminde iki buton ekleyelim ve şu kodları yazalım;

var ses:Sound = new Sound(new URLRequest("sarki.mp3"));
var kanal:SoundChannel=new SoundChannel();
 
basla_btn.addEventListener(MouseEvent.CLICK,basla)
durakla_btn.addEventListener(MouseEvent.CLICK,durakla)
var durmaPozisyonu:int = kanal.position;
 
function durakla(e:MouseEvent){
durmaPozisyonu = kanal.position;
kanal.stop();}
function basla(e:MouseEvent){
kanal = ses.play(durmaPozisyonu);}

Test edince göreceğiz ki basla_btn’ye basınca başlıyor, dur_btn’ye basınca duruyor ve daha sonra yine basla_btn’ye basınca kaldığı yerden oynamaya devam ediyor. Kodları açıklayacak olursak başta yine ses kanalı oluşturduk ve farklı olarak =new SoundChannel(); dedik, bunu açılır açılmaz çalmasın diye yaptık, eğer açılır açılmaz çalmasını istiyorsak bunu ilki gibi yani =ses.play() diye değiştirmeliyiz. Daha sonra farklı olarak durmaPozisyonu diye bir değişken atadık ve bunun ses kanalının o anki pozisyonu olduğunu bildirdik. Daha sonra ise durakla_btn’ye tıklama durumunda o anki durmaPozisyonu’nu kanal.position’a eşitledik, basla_btn’ye tıklama durumunda ise sesi durmaPozisyonu’nda kanala eşitleyerek başlattık. Şimdi bir kaç değişiklikle tam bir ses kontrol sistemi yapalım; sahneye dur_btn isminde bir buton daha ekleyin ve kodları şu şekilde değiştirin;

var ses:Sound = new Sound(new URLRequest("sarki.mp3"));
var kanal:SoundChannel=new SoundChannel();
var calmaVarmı:Boolean=false
 
basla_btn.addEventListener(MouseEvent.CLICK,basla)
durakla_btn.addEventListener(MouseEvent.CLICK,durakla)
dur_btn.addEventListener(MouseEvent.CLICK,dur)
var durmaPozisyonu:int = kanal.position;
 
function basla(e:MouseEvent){
if(!calmaVarmı){
calmaVarmı=true
kanal = ses.play(durmaPozisyonu)}
}
function durakla(e:MouseEvent){
if(calmaVarmı==true){
calmaVarmı=false
durmaPozisyonu = kanal.position;
kanal.stop();}
}
function dur(e:MouseEvent){
calmaVarmı=false
durmaPozisyonu = 0
kanal.stop();
}

Bundan önceki kodda basla_btn’ye iki kere basınca iki kere çalıyordu bunu engellemek için bir mantık sorgulayıcı olarak calmaVarmı diye bir boolean oluşturduk ve bunu başta çalma olmadığı için false’e eşitledik. Daha sonra da butonları çalma durumuna göre çalıştırmak için kodlar yazdık ve dur_btn için stop kodu ekledik ve durma pozisyonunu sıfır yaptık ki en başa dönsün… Ayrıca bir kaç yabancı işlemi de açıklayalım Fransız kalmayın; if(!calmaVarmı) bu kod if(calmaVarmı==false) ile aynı manadadır yani durum false ise demektir. int ise Number’dan farklı olarak sadece tam sayılar anlamındadır, Number tüm sayıları belirtir yani aslında Number da yazılabilirdi… Ayrıca uint de vardır bu da doğal sayılar anlamındadır… Ne güzel bir ses kontrol sistemimiz oldu… Bir sonraki yazıda kaldığımız yerden devam edeceğiz inşallah…

btn.doubleClickEnabled=true
btn.addEventListener(MouseEvent.DOUBLE_CLICK,tikla);
function tikla(e:MouseEvent){
trace("çift tıklandı");
}

Burada ilk satırdaki kod ile çift tıklama izni verdik daha sonra da fare olaylarından çift tıklamayla yapılacak fonksiyonu atadık…

stop()
loaderInfo.addEventListener(ProgressEvent.PROGRESS, yukle);
function yukle(event:ProgressEvent){
ust.width=alt.width*event.bytesLoaded/event.bytesTotal
if(event.bytesLoaded==event.bytesTotal){gotoAndStop(2)}
}

Bu kodda loaderInfo sınıfına ProgressEvent.PROGRESS yükleme anında yaplacaklar için atandı daha sonra yukle fonksiyonu bu anda çağırılmak için belirtildi. Yükle fonksiyonunda ilk satırda ust’ün genişliği eşittir alt’ın genişliği çarpı yüklenen byte bölü toplam byte işlemini gerçekleştirdik ve sonra eğer yüklenen byte toplam byte’a eşit olursa ikinci frame’e git dedik… Şimdi de bunun tamamını kodla yapalım yani sahneye bişey eklemeden kodla şekil çizelim;

stop()
var onyukleyici:Sprite=new Sprite();
addChild(onyukleyici)
var gen:uint=200; var yuk:uint=10
onyukleyici.x=stage.stageWidth/2-gen/2;
onyukleyici.y=stage.stageHeight/2-yuk/2
 
var alt:Shape=new Shape()
alt.graphics.beginFill(0X009900);
alt.graphics.drawRect(0,0,gen,yuk)
alt.graphics.endFill();
onyukleyici.addChild(alt);
 
var ust:Shape=new Shape()
ust.graphics.beginFill(0X00CC00);
ust.graphics.drawRect(0,0,1,yuk)
ust.graphics.endFill();
onyukleyici.addChild(ust);
 
loaderInfo.addEventListener(ProgressEvent.PROGRESS, yukle);
function yukle(event:ProgressEvent){
ust.width=alt.width*event.bytesLoaded/event.bytesTotal
if(event.bytesLoaded==event.bytesTotal){
gotoAndStop(2); removeChild(onyukleyici)}
}

Burada farklı olarak alt ve ust cubuğu kod ile çizdik ve bu iki çizimi onyukleyici sprite’ının içine yerleştirdik onyukleyici’yi de sahnenin ortasına konumlandırdık ve yükleme bitince removeChild ile onyukleyici’yi kaldırdık… Şimdi bu yüklenen yüzdelik dilimini yazıyla sahneye aktaralım, sahneye yuzde isimli bir dynamic text ekleyin ve yukarıdaki yukle fonksiyonunun içine şu kodları yazın;

yuzde.text="%"+Math.round(event.bytesLoaded/event.bytesTotal*100)

Bu kodda text’e yazılmasını istediğimiz şeyi belirttik yani yüklenen byte’ı toplam byte’a bölüp 100 ile çarparsak yüklenen byte yüzdesini buluruz, virgüllü sayı almamak için de bunu Math.round içine aldık. Eğer bunu da kodla yapmak istiyorsak ikinci verdiğimiz kodu şu şekilde değiştirmemiz gerekecek;

stop()
var onyukleyici:Sprite=new Sprite();
addChild(onyukleyici)
var gen:uint=200; var yuk:uint=10
onyukleyici.x=stage.stageWidth/2-gen/2
onyukleyici.y=stage.stageHeight/2-yuk/2
 
var alt:Shape=new Shape()
alt.graphics.beginFill(0X009900);
alt.graphics.drawRect(0,0,gen,yuk)
alt.graphics.endFill();
onyukleyici.addChild(alt);
 
var ust:Shape=new Shape()
ust.graphics.beginFill(0X00CC00);
ust.graphics.drawRect(0,0,1,yuk)
ust.graphics.endFill();
onyukleyici.addChild(ust);
 
var yuzde:TextField = new TextField();
var format:TextFormat = new TextFormat();
format.color = 0X006600; format.size = 15;
yuzde.defaultTextFormat = format;
yuzde.width=40; yuzde.height=20
yuzde.x=gen/2-yuzde.width/2; yuzde.y=10
yuzde.selectable = false
onyukleyici.addChild(yuzde)
 
loaderInfo.addEventListener(ProgressEvent.PROGRESS, yukle);
function yukle(event:ProgressEvent){
yuzde.text="%"+Math.round(event.bytesLoaded/event.bytesTotal*100)
ust.width=alt.width*event.bytesLoaded/event.bytesTotal
if(event.bytesLoaded==event.bytesTotal){
gotoAndStop(2); removeChild(onyukleyici)}
}

Bu kodda son anlattığımızdan farklı olarak yuzde isminde bir TextField oluşturduk sonra bunun yazıtipi için format adında bir TextFormat oluşturduk, formatın özelliklerini belirtip defaultTextFormat ile formatı yazıya yükledik daha sonra yuzde yazısının konum ve durumunu belirtip yine onyukleyici sprite’ının içine ekledik. Hepsi bu kadar… Bu arada preloader’ın yanında text sınıfından da bişeyler öğrendik 8) Ayrıca bu son kodu ilk frame’e eklerseniz hiçbişey yapmadan beleşten süper ötesi bir önyükleyiciye sahip olursunuz artık bundan sonra sırtınız yere gelmez…

niyazi_btn.addEventListener(MouseEvent.CLICK,git);
function git(e:MouseEvent){
navigateToURL(new URLRequest("http://pilav.wordpress.com"),"_blank" )
}

Şimdi kodu açıklayalım; Önce butonumza bir listener ekledik ve mouseClick anında git fonksiyonunu çalıştırmasını istedik. Sonra git fonksiyonunu yazdık ve linki verdik daha sonra da linki _blank ile, yani yeni bir sayfa ile aç dedik. Aynı sayfada açmak için _self yazarız veya hiç bişey yazmayız. Hepsi bu kadar…

var renk:ColorTransform = hedef_mc.transform.colorTransform;
renk.color = 0xFF0000
hedef_mc.transform.colorTransform = renk

Gördüğünüz gibi hedef_mc’mizi kırmızı yaptık. Şimdi artistlik yapmaya devam ediyoruz;

var renk:ColorTransform = hedef_mc.transform.colorTransform;
addEventListener(Event.ENTER_FRAME,sapitma)
function sapitma(e:Event){
renk.color = 0xFF0000*Math.random()
hedef_mc.transform.colorTransform = renk}

Burada da hedef_mc’nin rengini Math.random() (yani 0-1 arası rastgele bir sayı) ile çarpıp rastgele renk elde ettik ve bunu EnterFrame ile sürekli tekrarladık böylece hedef_mc’miz renk manyağı oldu…

Şimdi artistlik eylemlerine devam ediyoruz 8) Şu kodları ekleyin;

var gen:uint=20
for(var i:uint=0;i<200;i++){
var mc:Shape = new Shape();
mc.graphics.beginFill(0X000000 ,1)
mc.graphics.drawRect(0,0,18,18 )
mc.graphics.endFill();
mc.name="kare"+String(i);
var renk:ColorTransform = mc.transform.colorTransform;
renk.color = i*0xFF0000+0xFF0000
mc.transform.colorTransform = renk;
var a:uint=i%gen; var b:uint=i/gen
mc.x=a*18+40; mc.y=b*18+20
addChild(mc);}

Örnek uygulama için tıklayın. Evet burada kırmızı spektrum görüyorsunuz, yani kırmızı ve tonlarını. (renk.color = i*0xFF0000+0xFF0000 şu koddaki renkleri değiştirirseniz daha tarzanca renkler elde edebilirsiniz. Mesela şu renkle değiştirin ikisini de; 0xFF0cc0) Aslında Tüm renklerden oluşan bir spektrum yapayım dedim ama o kadar tıp bilmiyormuşum demek ki, olmadı Neyse onu da sonra şeettiririz de şimdi bu kodları açıklayalım; Önce, bir önceki yazıda da yaptığımız gibi for döngüsü oluşturduk ve içindeki kareyi çoğalttık ve her kareye mc.name="kare"+String(i); kodu ile yeni bir isim verdik, sonra colorInfo.color = i*0xFF0000 + 0xFF0000 koduyla kırmızı rengini sürekli artan i sayısıyla çarpıp kırmızı renk tonlarını yakaladık ve bu rengi karelere atadık daha sonra kareleri dizdik (% kodu mod anlamında kullanılır bunu daha sonra ayrıntılı açıklayabilirim belki) ve mc’i sahneye ekledik.

Şimdi renk sınıfının diğer özelliklerine bakalım, yukarıdaki kodda renk.color = i*0xFF0000+0xFF0000 satırının altına şunu ekleyin;

renk.alphaMultiplier=i/200

Evet bu kod rengin alpha değeri ile oynuyor. Neyse bu yazı uzun oldu diğer sınıf şeyslerini de sonra şeettiririz artık

for(var i=0;i<10;i++){
var yeni_mc:kare=new kare();
yeni_mc.name="kare"+String(i);
yeni_mc.x=i*20+40
yeni_mc.y=i*20+20
addChild(yeni_mc);}

Bu kodu çalıştırabilmemiz için kütüphanede linkage class kısmına ‘kare’ yazılmış bir kare movieClip’imizin olması gerekiyor. Görüldüğü gibi mc’mizi 10 adet çoğalttık. Yeni isim vermede de "kare"+String(i); ifadesini kullandık. As2′de depht numaraları veriliyordu fakat burada ona gerek kalmadı, artık depth otomatik olarak kuruluyor. swapDepth ifadesi yerine de swapChildren kullanılıyor.



var zaman:Timer=new Timer(100);
zaman.addEventListener(TimerEvent.TIMER,calistir);
zaman.start();
function calistir(e:TimerEvent) {
cisim.x+=10;
}

Bu kodda önce zaman’ın bir Timer nesnesi olduğunu tanımladık (buradaki 100 sayısı saniyenin onda birini ifade eder yani 1 sn’yi 1000 olarak ifade ediyoruz) daha sonra bir listener ekleyip calistir fonksiyonunu buna tanımladık. zaman.start(); koduyla timer işlemini başlattık en son olarak da yukarda bahsettiğimiz calistir fonksiyonunu yazarak sahnedeki cisim movieClip’ini x yönünde 10px kaydırıyoruz. Şimdi bu Timer’ı durdurmayı deneyelim;

var zaman:Timer=new Timer(100);
zaman.addEventListener(TimerEvent.TIMER,calistir1);
zaman.start();
function calistir1(e:TimerEvent) {
cisim.x+=10;
if(cisim.x>100){zaman.stop();}
}

Burada fazladan zaman.stop(); işlemini kullandık, yani cisim.x 100′den büyük olunca Timer’ı durduruyoruz. Şimdi TIMER_COMPLETE işlemine bakalım;

var zaman:Timer=new Timer(1000,10);
zaman.addEventListener(TimerEvent.TIMER,calistir1);
zaman.addEventListener(TimerEvent.TIMER_COMPLETE,calistir2);
zaman.start();
function calistir1(e:TimerEvent) {
cisim.x+=10;
}
function calistir2(e:TimerEvent) {
trace("bitti" )
}

TIMER_COMPLETE ile timer bitince yapılacaklar anlatılır. İlk satırdaki new Timer(1000,10); kodu bu işlemin 10 kere 1sn aralıklarla yapılmasını emreder, aşağıda da calistir2 fonksiyonu ile bu işlemin bitmesi halinde yapılacaklar yukardaki TIMER_COMPLETE aracılığı ile belirtilir. Bu kodda cisim.x 1sn aralıkla 10 defa 10′ar 10′ar artacak ve işlem bittiğinde output "bitti" diyecektir.

stage.addEventListener(Event.ENTER_FRAME,calistir)
function calistir(e:Event){
var numara:Number = mouseX
var yazi:String = numara.toString();
kutu.text=yazi
}

Bu kodları çalıştırabilmek için sahnede kutu isimli bir dyn. text olmalıdır. Bu kodlar ile enterFrame içinde numara’yı mouse x’ine eşitledik sonra yazi’nin bir string olduğunu ve bu yazi’nin numara’nın string’e çevrilmiş hali olduğunu belirttik ve daha sonra da kutu.text’i yazi’ya eşitledik böylece kutu text’de sürekli olarak mouseX gösterilecek.

stage.scaleMode = StageScaleMode.NO_SCALE
stage.align = StageAlign.TOP_LEFT
stage.addEventListener(Event.RESIZE, yeniboyut)
kutu1.x=stage.stageWidth/2
kutu1.y=stage.stageHeight/2
kutu2.x=stage.stageWidth-kutu2.width/2
kutu2.y=stage.stageHeight-kutu2.height/2
function yeniboyut(event:Event){
kutu1.x=stage.stageWidth/2
kutu1.y=stage.stageHeight/2
kutu2.x=stage.stageWidth-kutu2.width/2
kutu2.y=stage.stageHeight-kutu2.height/2
}

Şimdi bu kodu açıklayalım. İlk iki satırdaki kodun işlevini geçen yazıda açıklmıştım, sonraki satırda ise bir dinleyici ile RESIZE durumunda çağıralacak fonksiyon(yeniboyut) belirtiliyor, ondan sonra bu fonksiyonun işlevi (fonksiyonun fonksiyonu yazacaktım azdaha ) belirtiliyor ki bu hadiseyi daha önceden anlatmıştım.
Bu koda göre sahnede bulunan ve kutu1 ile kutu2 instance name’li iki kutumuzu resize(yeniden boyutlanma) durumunda yeniden konumlandırıyoruz. Kutu1 ve kutu2′nin ilk konumlarını fonksiyondan önce yazdık (Dikkat ederseniz x ve y konumları için alt çizgi artık yok, hatta alt çizgi hiç bişeyde yok ) fonksiyon içine ise sayfayı yeniden boyutlandırınca bulunacakları konumu yazdık. Buna göre kutu1 sayfanın ortasında, kutu2 ise sayfanın sağ alt kısmında duracak. Bu konum yerine genişlik yükseklik falan da yapabiliriz, bunun için x yerine width, y yerine height falan yazmamız yetecektir.
Örnek uygulama için tıklayın. (Ekran boyutunu değiştirmeyi unutmayın )

As2′de kullandığımız, sağ tık menüyü ve flash player menüsünü kapatmaya yarayan Stage.showMenu = false; kodu yerine;

stage.showDefaultContextMenu = false

As2′de %100 görüntü sağlayan, skalayı kaldıran Stage.scaleMode = "noScale" kodu yerine;

stage.scaleMode = StageScaleMode.NO_SCALE

As2′de hizalama referansını gösterdiğimiz örneğin Stage.align = "lt" kodu yerine;

stage.align = StageAlign.TOP_LEFT

Ekran yüksekliği Stage.height yerine;

stage.stageHeight

Ekran genişliği Stage.width yerine;

stage.stageWidth

Kodlarını kullanıyoruz. Stage ile AS3′te daha çok işlev var ama daha oralara gelmedik, hele bi durun